Hallo Holdrio,

möglich ist das schon. Allerdings nur mit VBA und auch nur indem man mit einer sog. API, die Windowsstyle-Eigenschaften verändert. Aber nicht alles was möglich ist, sollte man auch tun. Grade wenn du die Titelleiste ausblendest, hast du dann kaum noch eine Möglichkeit das Fenster wieder zu schließen oder zu verschieben. Von daher schließe ich mich dem Vorredner an. Powerpoint ist eindeutig die bessere Wahl. Man kann dort eingefügte Bilder auch mit Excel verknüpfen, sodass sie sich automatisch updaten.

Was stört dich denn an der Titelleiste? Die ist so schmal, dass sie doch gar nicht auffällt.

Wenn du unbedingt ein komplettes Vollbild brauchst, dann probier mal das folgende Makro:

Private Declare PtrSafe Function SetWindowLong Lib "user32.dll" _
  Alias "SetWindowLongPtrA" ( _
  ByVal hwnd As LongPtr, _
  ByVal nIndex As Long, _
  ByVal dwNewLong As Long) As Long
Private Declare PtrSafe Function GetWindowLong Lib "user32" _
  Alias "GetWindowLongPtrA" ( _
  ByVal hwnd As LongPtr, _
  ByVal nIndex As Long) As Long
 
Private Const GWL_STYLE = -16 ' Ermittelt die StandardFensterstyles
 
' einige Standard-Fensterstile
Private Const WS_OVERLAPPED = &H0
Private Const WS_SYSMENU = &H80000
Private Const WS_THICKFRAME = &H40000  ' Rahmen des Fensters
Private Const WS_CAPTION = &HC00000    ' Titelleise des Fensters
Private Const WS_MAXIMIZEBOX = &H10000 ' Maximierenbutten des Fensters
Private Const WS_MINIMIZEBOX = &H20000 ' Minimierenbutton des Fensters

Sub Vollbild()
   
  Dim TmpStyles As Long
  
  'ActiveWindow.DisplayHeadings = Application.DisplayFullScreen
  Application.DisplayScrollBars = Application.DisplayFullScreen
  Application.DisplayFullScreen = Not Application.DisplayFullScreen
  Application.DisplayFormulaBar = Not Application.DisplayFullScreen
  Application.DisplayStatusBar = Not Application.DisplayFullScreen
 
  'Aktuelle Fensterstile bekommen
  TmpStyles = GetWindowLong(Application.hwnd, GWL_STYLE)
 
  ' Fensterstile Titelleiste aus-/einblenden
  TmpStyles = TmpStyles Xor WS_OVERLAPPED Xor WS_CAPTION Xor WS_SYSMENU Xor WS_THICKFRAME Xor WS_MINIMIZEBOX Xor WS_MAXIMIZEBOX
 
  ' Neue Fensterstile setzen
  Call SetWindowLong(Application.hwnd, GWL_STYLE, TmpStyles)
  
  ' endgültiges Vollbild
  Application.WindowState = xlMinimized
  Application.WindowState = xlMaximized
  
End Sub

Tipp: Bevor du das Makro ausführst solltest du es einer Tastenkombination zuweisen. Drück dazu in Excel Alt+F8 wähle im Makro-Menü, das Makro und klick auf den Button Optionen. Dort kannst du dann also Buchstaben z.B. ein kleines g eintragen. Ab sofort kannst du mit STRG+G den Vollbild-Modus ein oder wieder ausschalten. Wenn du zuvor auch die Windows-Taskleiste ausblendest hast du ein komplettes Vollbild.

In Excel 2010 wird bereits VBA7 unterstützt und somit die PtrSafe-Funktion. Sollte das nicht so sein oder du das Makro in früheren Office-Versionen einsetzen wollen, dann schmeiß' PtrSafe sowie die Buchstabenkombination Ptr per Suchen und Ersetzen überall raus.

Bei weiteren Problemen einfach melden

Gruß Mr. K.