Vorschlag zur Gemütlichkeit:

Option Explicit

Sub Allesamt()

Dim oTargetSheet As Excel.Worksheet          'mein Ziel, wo später als CSV
Dim oSourceBook As Excel.Workbook            'Quelle(n)
Dim sPfad As String
Dim sDatei As String
Dim Flag As Boolean                          'Schalter ob
Dim TargetRange As Range                     'Zielzelle
Dim strNeuCSV As String                      'Datei speichern unter
        
   Application.ScreenUpdating = False 'Das "Flackern" ausstellen
   Application.DisplayAlerts = False 'Keine Fehlermeldungen anzeigen
                
   'Schleife über alle Excel Dateien in einem Verzeichnis
   'sPfad = "Z:\dep_Controlling-WSA\07 Monatsabschluss\ILV-Makros\Stundenerfassung\Einzelbelege\"
        
        '****************************************
        ''Pfad zum Test geändert
        sPfad = ThisWorkbook.Path & "\MeinTest\"
        '****************************************
        '
        
   sDatei = Dir(sPfad & "*.xlsx*")    'Alle Excel Dateien
   
   Do While sDatei <> ""
        
      'Öffnen der Datei und Datenübertragung
      If Not Flag Then
         'Anfang - erste xlsx
         Set oSourceBook = Workbooks.Open(sPfad & sDatei)
         oSourceBook.Sheets(1).Copy
         'hurra - neue Mappe
         Set oTargetSheet = ActiveWorkbook.Sheets(1)
         'im einzigen Arbeitsblatt
         With oTargetSheet
            'Quellangabe
            .Rows(1).Insert
            .Cells(1).Value = oSourceBook.Name
            With .UsedRange
               'nächstes Kopierziel
               Set TargetRange = .Rows(.Rows.Count).Cells(1).Offset(2)
            End With
         End With
         oSourceBook.Close False
         '
         'nie mehr wieder
         Flag = True
         '
      Else
         '
         'weitere - xlsx
         Set oSourceBook = Workbooks.Open(sPfad & sDatei)
         'Inhalt ins Ziel
         oSourceBook.Sheets(1).UsedRange.Copy TargetRange
         'Quellangabe - in die leere Zeile vor
         TargetRange.Offset(-1).Value = oSourceBook.Name
         oSourceBook.Close False
         'nächstes Kopierziel
         With oTargetSheet.UsedRange
            'nächstes Kopierziel
            Set TargetRange = .Rows(.Rows.Count).Cells(1).Offset(2)
         End With
         '
      End If
      
      sDatei = Dir
                                                      
   Loop
                       
   'als CSV speichern
   strNeuCSV = InputBox("CSV-Dateiname ", "Speichern unter", "Test")
   If Len(strNeuCSV) Then
      strNeuCSV = Replace(strNeuCSV, ".", "")
      strNeuCSV = Replace(LCase(strNeuCSV), "csv", "")
      With oTargetSheet.Parent
         .SaveAs Filename:=sPfad & strNeuCSV & ".csv", _
            FileFormat:=xlCSV, CreateBackup:=False, Local:=True
         .Close True
      End With
      
   Else
      Call MsgBox("aktive Datei " & oTargetSheet.Parent.Name, vbExclamation)
   End If
                       
End Sub