Hallo,

in der Word Version 2021 wird unter jeder Tabelle immer ein Absatzmarke eingefügt. Diese kann manin dieser Version nicht entfernen.

Wenn bei Deiner Word Version eine Tabelle auch ohne nachfolgender Absatzmarke ersteltl werden kann, wäre es Interressant zu erfahren, welche Version hier eingesetzt wird.

In der angepassten VBA-Befehl wird keine Endlosschleife mehr verursacht:

Sub BearbeiteWordDatei(filePath As String, templateDocPortrait As Document, templateDocLandscape As Document)
    Dim doc As Document
    Dim orientation As String
    Dim rngTmp As Range, lngTmp As Long
    Dim template As Document
    Dim headFoot As HeaderFooter
    ' Lade das Word-Dokument
    Set doc = Documents.Open(filePath)

    ' Bestimme die Ausrichtung des Dokuments
    orientation = doc.PageSetup.orientation
    
    With doc.Sections(1).Footers(wdHeaderFooterPrimary)
        Select Case doc.PageSetup.orientation
            ' Füge die entsprechende Fußzeile ein
            Case wdOrientPortrait
                Set template = templateDocPortrait
            Case wdOrientLandscape
                Set template = templateDocLandscape
        End Select
        
        Set headFoot = template.Sections(1).Footers(wdHeaderFooterPrimary)
        headFoot.Range.Copy
        .Range.Paste
        
        ' Textlängen abgleichen
        Do While .Range.StoryLength > headFoot.Range.StoryLength
            Set rngTmp = .Range
            rngTmp.Start = rngTmp.End - 1
            lngTmp = rngTmp.StoryLength
            rngTmp.Delete
            If rngTmp.StoryLength = lngTmp Then
                Exit Do
            End If
        Loop
    End With
    ' Speichere das aktualisierte Dokument
    doc.Save
    doc.Close SaveChanges:=False
    Set doc = Nothing
End Sub

Hier wird die Storylänge vor dem Entfernen des letzten Zeichens ausgelesen und nah dem Entfernen nochmals verglichen, wenn sich die StoryLänge nicht geändert hat, wird kein weiterer Versuch unternommen.

Um das Positions-Problem angehen zu können, brauche ich eine Beispiel-Datei, um zu erfahren, wie die Tabelle positioniert wurde. Bitte sende eine Datei einfach an dsoetebeer @ web.de