Hi Norbert,

hast du dich zu dem Thema bereits im Internet mal umgesehen?
Den Anschein hat es jedenfalls nicht... was die hohe View-Anzahl dieses Themas ohne jegliche Reaktion darauf erklärt/rechtfertigt.
Dieses Forum ersetzt NICHT deine eigene Recherche zu dem Thema!!! Ein Forum wie dieses kommt erst im Anschluss darauf in Frage.

Ein erster - und simpler - Versuch wäre, es über die Workbook.BuildinDocumentProperties Auflistung zu versuchen:

Es wird davon ausgegangen, dass die Mappe bereits in Excel geöffnet vorliegt und DeineMappe.xlsx heißt

Option Explicit

Sub SimpleExample()
  
  Dim objProperty As Object
  Dim vntCreationDate As Variant
  Dim vntLastSaved As Variant
  Dim vntLastAuthor As Variant
  Dim blnValid As Boolean
  
  For Each objProperty In Workbooks("DeineMappe.xlsx").BuiltinDocumentProperties
    
'    Call DebugPrintProperty(objProperty)
    
    If TypeOf objProperty Is DocumentProperty Then
      
      Select Case objProperty.Name
        Case "Creation date":   vntCreationDate = objProperty.Value
        Case "Last save time":  vntLastSaved = objProperty.Value
        Case "Last author":     vntLastAuthor = objProperty.Value
      End Select
      
    Else
      Stop
    End If
    
    If Not ( _
      IsEmpty(vntCreationDate) _
      Or IsEmpty(vntLastSaved) _
      Or IsEmpty(vntLastAuthor)) _
    Then
      blnValid = True
      Exit For
    End If
    
  Next
  
  If blnValid Then
    Debug.Print String$(75, "-")
    Debug.Print "['Creation Date']: "; Format$(vntCreationDate, "yyyy-mm-dd hh:nn:ss")
    Debug.Print "['Last Saved']: "; Format$(vntLastSaved, "yyyy-mm-dd hh:nn:ss")
    Debug.Print "['Last Author']: "; "'"; vntLastAuthor; "'"
  Else
    Debug.Print "NO_DATA_FOUND"
  End If
  
End Sub

'Private Sub DebugPrintProperty(ByVal Property As Object)
'  On Error Resume Next
'  Debug.Print "'"; Property.Name; "'"; Tab(25);
'  If Err.Number Then Exit Sub
'  Debug.Print " -> (" & Property.Value & ")"
'  If Err.Number Then Debug.Print "    NO_VALUE_AVAILABLE"
'  On Error GoTo 0
'End Sub

Sollte das allein nicht genügen, findest du im Internet weitere Lösungsmöglichkeiten; diese gehen dann für gewöhnlich den Weg über Web-Requests.

Grüße