"Zicken" wird er vermutlich nicht wegen der leeren Zellen, sondern wegen Ausdrücken, die er nicht auflösen kann; dann fragt er einen nämlich per Dialog (der ggf. im Hintergrund liegt / nicht sichtbar ist).

Ich würde vorschlagen, dir den Inhalt des Bereichs mit den Empfängern in ein 1D-Array geben zu lassen;
und zwar nach folgendem Prinzip:

Option Explicit

Public Sub Test()
  
  'Worksheets("XXXXX").Activate
  'ActiveSheet.Copy
  
  'Set OutApp = CreateObject("Outlook.Application")
  
  Dim vntRecipients As Variant
  vntRecipients = GetRecipientsFromRange(ActiveSheet.Range("U9", "U29"))
  
  If UBound(vntRecipients) > 0 Then
    Application.Dialogs(xlDialogSendMail).Show vntRecipients, "Betreff"
  End If
  
  'ActiveWorkbook.Close SaveChanges:=False
  
End Sub

Public Function GetRecipientsFromRange(RangeWithRecipients As Excel.Range)
  
  Dim rngRecipient As Excel.Range
  Dim vntRecipients As Variant 'notwendig wegen Split(Empty)
  Dim vntRecipient As Variant
  Dim i As Long
  
  ReDim vntRecipients(1 To RangeWithRecipients.Cells.Count)
  
  For Each rngRecipient In RangeWithRecipients.Cells
    vntRecipient = Trim(rngRecipient.Value)
    If ValidateRecipient(vntRecipient) Then
      i = i + 1
      vntRecipients(i) = vntRecipient
    End If
  Next
  
  If i > 0 Then
    ReDim Preserve vntRecipients(1 To i)
  Else
    vntRecipients = Split(Empty)
  End If
  
  GetRecipientsFromRange = vntRecipients
  
End Function

Public Function ValidateRecipient(Recipient As Variant) As Boolean
  ' Logik zur Bestimmung ob gültig / nicht gültig
  ' (wie auch immer diese Logik ausschauen mag)

  ' * Das hier ist nur ein ganz simples Beispiel *
  ValidateRecipient = Recipient <> ""
End Function