Beispieltext:

Der Stirnlappenbasilisk erreicht eine Länge von rund 80 cm, wovon die Länge des Schwanzes mit 50 bis 55 cm zwei Drittel der Gesamtlänge beträgt. Namensgebend sind die Stirnlappen (die bei den Männchen deutlicher ausgeprägt sind und die Form eines Kopfsegels haben) auf dem Kopf und Hinterkopf des Basilisken. Der Körper ist insgesamt schlank gestaltet, die Beine sind dennoch kräftig gebaut. Die Färbung der Schuppen variiert zwischen dunkelgrün über smaragdgrün bis blaugrün. Zur Bauchseite hin werden die Schuppen heller. Der Rücken ist durch eine gelbliche bis bläuliche Sprenkelung gezeichnet. Die eindrucksvollen Hautkämme auf dem Rücken, die eine Höhe von 5 cm erreichen können, setzen sich bis zur Schwanzwurzel fort. Diese Hautkämme sind beim Weibchen etwas weniger stark ausgeprägt. Die Tiere können in Gefangenschaft bei guter Pflege bis zu 13 Jahre alt werden. In Freiheit sterben sie allerdings deutlich früher.

Option Explicit

Sub Test()
  
  Dim rngWord As Word.Range
  Dim dic     As Object 'Scripting.Dictionary
  Dim k       As Long
  Dim k_min   As Long
  Dim k_max   As Long
  
  Set dic = CreateObject("Scripting.Dictionary")
  
  'Formatierung aus vorherigen Durchgang rückgängig machen
  ThisDocument.Range.Font.Reset
  ThisDocument.Range.HighlightColorIndex = wdAuto
  
  'Spaltenbeschriftung der Ausgabe zur Kontrolle im Direktfenster (STRG+G)
  Debug.Print "WORT"; Tab(25); "ANZ"; Tab(30); "POS"
  
  'Wortweise durch den Text bewegen
  For Each rngWord In ThisDocument.Words
    
    'Leerzeichen am Ende eines Wortes weglassen - seltsames Verhalten von Word ¯\_('-')_/¯
    rngWord.MoveEndWhile " ", wdBackward
    
    'unsere Hilfsfunktion aufrufen (siehe unten)
    k = Complexness(rngWord)
    
    If k > 0 Then
      
      'wir merken uns hier gleich den kleinsten und größten k-Wert
      If k < k_min Or k_min = 0 Then k_min = k
      If k > k_max Or k_max = 0 Then k_max = k
      
      'wir nehmen das Wort (also das Word.Range-Objekt) in die Liste auf
      ' weitere Wörter interessieren uns nicht, bei gleicher Komplexität 'k'
      '  - uns interessiert nur das erste Vorkommen
      If Not dic.Exists(k) Then
        
        Call dic.Add(k, rngWord)
        
        'Ausgabe zur Kontrolle im Direktfenster (STRG+G)
        Debug.Print "'"; rngWord.Text; "'"; Tab(25); k; Tab(30); rngWord.Start
      End If
      
    End If
  Next
  
  'einfachste Wort (kleinste Komplexität 'k')
  With dic(k_min) '<- liefert Word.Range-Objekt
    .HighlightColorIndex = WdColorIndex.wdGreen
    .Font.ColorIndex = WdColorIndex.wdWhite
  End With
  
  'komplizierteste Wort (größte Komplexität 'k')
  With dic(k_max) '<- liefert Word.Range-Objekt
    .HighlightColorIndex = WdColorIndex.wdRed
    .Font.ColorIndex = WdColorIndex.wdWhite
  End With
  
End Sub

'Hilfsfunktion
' stellt fest wie kompliziert/komplex ein Wort ist
Private Function Complexness(Word As Word.Range) As Long
  
  Dim rngChr  As Word.Range
  Dim dic     As Object 'Scripting.Dictionary
  
  Set dic = CreateObject("Scripting.Dictionary")
  'wir wollen 'A' von 'a' unterscheiden -> binary compare
  dic.CompareMode = VbCompareMethod.vbBinaryCompare
  
  For Each rngChr In Word.Characters
    Select Case rngChr.Text
      'uns geht es hier nur um Buchstaben
      Case "a" To "z", "A" To "Z", "ä", "ö", "ü", "ß"
        'wir zählen hier aus "Spaß" gleich noch die
        'Anzahl gleicher Zeichen mit (z.B. wie oft kommt 'a' in »Banane« vor)
        ' mit der Information fangen wir hier aber nichts weiter an
        dic(rngChr.Text) = dic(rngChr.Text) + 1
    End Select
  Next
  
  'Anzahl unterschiedlicher Zeichen
  Complexness = dic.Count
  
End Function

Grüße