Thema
|
Datum
|
Von Nutzer
|
Rating
|
Antwort
|
|
11.02.2021 15:26:26 |
Bernd |
|
|
Kopieren geht in die falsche Richtung |
12.02.2021 00:40:44 |
Gast34412 |
|
|
|
12.02.2021 14:35:33 |
Bernd |
|
|
Von:
Gast34412 |
Datum:
12.02.2021 00:40:44 |
Views:
470 |
Rating:
|
Antwort:
|
Thema:
Kopieren geht in die falsche Richtung |
Hi Bernd.
Ich hab' versucht deine Beschreibung ein wenig zu entwirren und im Code möglichst klar abzubilden:
(ungetestet)
Option Explicit
Sub Austausch_MAS_Ticketing()
Dim wksQ As Worksheet 'Quelle
Dim rngQMeldungsNr_Spalte As Range
Dim wksZ As Worksheet 'Ziel
Dim rngZMeldungsNr_Spalte As Range
Set wksQ = ActiveWorkbook.ActiveSheet
Set wksZ = Workbooks("Ticketing TMZ").Worksheets("Tickets")
With wksQ
'Datenbereich anhand Spalte B ermitteln
Set rngQMeldungsNr_Spalte = .Range("B2", .Cells(.Rows.Count, "B").End(xlUp))
If rngQMeldungsNr_Spalte.Row < 2 Then
Set rngQMeldungsNr_Spalte = Nothing
End If
End With
With wksZ
'Datenbereich anhand Spalte A ermitteln
Set rngZMeldungsNr_Spalte = .Range("A2", .Cells(.Rows.Count, "A").End(xlUp))
If rngZMeldungsNr_Spalte.Row < 2 Then
Set rngZMeldungsNr_Spalte = Nothing
Else
'den gleichen Datenbereich in Spalte V referenzieren
Set rngZMeldungsNr_Spalte = rngZMeldungsNr_Spalte.Offset(ColumnOffset:=.Columns("V").Column - rngZMeldungsNr_Spalte.Column)
End If
End With
If rngQMeldungsNr_Spalte Is Nothing _
Or rngZMeldungsNr_Spalte Is Nothing _
Then
Call MsgBox("Es wurden keine Daten zum Verarbeiten gefunden.", _
vbExclamation, _
"MAS_Ticketing")
Else
Dim rngQMeldungsNr As Range
Dim rngZFund As Range
'schrittweise alle Zellen in rngQMeldungsNr_Spalte abarbeiten ...
For Each rngQMeldungsNr In rngQMeldungsNr_Spalte.Cells
'suche MeldungsNr aus der Quelle im Ziel
Set rngZFund = rngZMeldungsNr_Spalte.Find( _
What:=rngQMeldungsNr.Value, _
LookAt:=xlWhole, _
LookIn:=xlValues)
If Not rngZFund Is Nothing Then
'überträgt Wert von Quelle (Spalte N) nach Ziel (Spalte AA)
wksZ.Cells(rngZFund.Row, "AA").Value = wksQ.Cells(rngQMeldungsNr.Row, "N").Value
' Call wksQ.Cells(rngQMeldungsNr.Row, "N").Copy(Destination:=wksZ.Cells(rngZFund.Row, "AA"))
End If
Next
Call MsgBox("Vorgang abgeschlossen.", _
vbInformation, _
"MAS_Ticketing")
End If
End Sub
|
- Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
- Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
- Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
- Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
- Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei
Antworten auf Ihren Beitrag zu benachrichtigen
Bitte geben Sie ein aussagekräftiges Thema an.
Bitte geben Sie eine gültige Email Adresse ein!
- Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
- Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
- Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
- Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
- Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei
Antworten auf Ihren Beitrag zu benachrichtigen
Thema
|
Datum
|
Von Nutzer
|
Rating
|
Antwort
|
|
11.02.2021 15:26:26 |
Bernd |
|
|
Kopieren geht in die falsche Richtung |
12.02.2021 00:40:44 |
Gast34412 |
|
|
|
12.02.2021 14:35:33 |
Bernd |
|
|