Um sich ein Bild von der Mail machen zu können, wäre es besser du kopierst den Inhalt der Beispiel-Mail (per Code-Snipped Funktion in der Beitragserstellung; Einfügen per Tastenkombi STRG+V).

Wenn du die Mail geöffnet hast, einfach Rechtsklick in den Nachrichtentext > "Quelle anzeigen". Den angezeigten Text dann kopieren und hier einfügen.

Alternativ kannst du auch das Makro hier benutzen:

> Dazu einfach die betreffende Mail im Explorer auswählen (d.h. nicht öffnen). Der Inhalt wird dann in die Windows-Zwischenablage kopiert und die kannst du dann hier direkt, wie oben beschrieben, einfügen.

Option Explicit

Sub CopySelectedMailBody2Clipboard()
  
  Dim objExplorer As Outlook.Explorer
  Dim objMailItem As Outlook.MailItem
  Dim strMailContent As String
  
  Set objExplorer = ActiveExplorer
  
  If objExplorer.Selection.Count >= 1 Then
    'erstes Item muss ein MailItem sein
    If TypeOf objExplorer.Selection(1) Is Outlook.MailItem Then
      
      'MailItem referenzieren
      Set objMailItem = objExplorer.Selection(1)
      
      If objMailItem.BodyFormat = olFormatHTML Then
        'Mail-Inhalt als HTML oder Plain-Text übernehmen?
        Select Case MsgBox("Der EMail-Inhalt liegt im HTML-Format vor." & vbNewLine & vbNewLine & _
                           "Möchten Sie den EMail-Inhalt im HTML-Format übernehmen?" & vbNewLine & _
                           "(Ja ... HTML / Nein ... Text)", _
                           vbYesNoCancel + vbQuestion)
          Case vbYes
            'wird als HTML übernommen
            strMailContent = objMailItem.HTMLBody
          Case vbNo
            'wird als Text übernommen
            strMailContent = objMailItem.Body
          Case Else
            Exit Sub
        End Select
      Else
        strMailContent = objMailItem.Body
      End If
      
      'new MSForms.DataObject (=Clipboard)
      With CreateObject("new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")
        Call .SetText(strMailContent)
        Call .PutInClipboard
      End With
      
      Call MsgBox("Der Mail-Inhalt wurde in die Zwischenablage kopiert.", vbInformation)
      
    Else
      Call MsgBox("Keine EMail-Nachricht ausgewählt.", vbExclamation)
    End If
  End If
  
End Sub