Ungetestet.

Option Explicit

Sub Test123()

  Dim objFilePickerDlg As Office.FileDialog

'# Datei-Auswahl-Dialog (Mehrfachauswahl) >>
  Set objFilePickerDlg = Application.FileDialog(msoFileDialogFilePicker)
  objFilePickerDlg.AllowMultiSelect = True
  objFilePickerDlg.Title = "Bitte Dateien auswählen..."
  objFilePickerDlg.Filters.Delete
  objFilePickerDlg.Filters.Add "Excel-Dateien", "*.xlsx,*.xls"

  If objFilePickerDlg.Show = 0 Then Exit Sub
'# Datei-Auswahl-Dialog (Mehrfachauswahl) <<

  Dim wkb As Excel.Workbook
  Dim wks As Excel.Worksheet
  Dim rng As Excel.Range
  Dim i As Long
  Dim j As Long

'# Verarbeitung/Daten kopieren (Dateien) >>

  Application.ScreenUpdating = False

  'Zielort: Erste Zelle für Ausgabe (ggf. anpassen)
  Set rng = ThisWorkbook.ActiveSheet.Range("A2")

  For i = 1 To objFilePickerDlg.SelectedItems.Count
    
    'Datenquelle öffnen und Daten von Blatt lesen
    Set wkb = Workbooks.Open(objFilePickerDlg.SelectedItems(i), ReadOnly:=True)
    Set wks = wkb.Worksheets(1) 'wkb.Worksheets("Tabelle1")

    'Werte in Zeile nebeneinander schreiben
    rng.Offset(0, 0).Value = wks.Range("D6").Value 'D6 - Lieferdatum
    rng.Offset(0, 1).Value = wks.Range("D2").Value 'D2 - wer hat bestellt
    rng.Offset(0, 2).Value = wks.Range("I7").Value 'I7 - Bestellsumme

    If i < objFilePickerDlg.SelectedItems.Count _
      Then Set rng = rng.Offset(1)

    Call wkb.Close(False)

  Next

  'Daten-Bereich ref.
  Set rng = rng.Offset(1 - objFilePickerDlg.SelectedItems.Count).Resize(objFilePickerDlg.SelectedItems.Count, 3)

  'nach erster Spalte sortieren (Lieferdatum)
  With rng.Worksheet.Sort
    Call .SortFields.Clear
    Call .SortFields.Add2(Key:=rng.Columns(1), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal)
    Call .SetRange(rng)
    Call .Apply
  End With

  Application.ScreenUpdating = True
  
  Call MsgBox("Fertig.", vbInformation)
  
End Sub