Moin Sammi,

ein Möglichkeit:

Option Explicit

Sub openTemplateWithTextbox()
    Dim sTemplate As String
    Dim Vorlage As Outlook.AppointmentItem
    Dim insp As Outlook.Inspector
    Dim wdDoc As Word.Document
    Dim sh As Word.Shape
 
    On Error GoTo FinisErr
    ' Pfad zur Vorlage festlegen
    sTemplate = "C:\Users\marco.sechi\AppData\Roaming\Microsoft\" & _
     "Templates\Unbenannt.oft"
    ' Vorlage versuchen zu laden
    Set Vorlage = Outlook.CreateItemFromTemplate(sTemplate)
    ' Fehler?
    If Vorlage Is Nothing Then
        MsgBox "Die Vorlage """ & sTemplate & """ konnte nicht geöffnet werden." _
            , vbCritical + vbOKOnly, "Vorlage öffnen"
        Exit Sub
    End If
    ' Vorlage anzeigen für Inspector
    Vorlage.Display
    'Insepctor für Zugriff auf Text
    Set insp = Outlook.ActiveInspector
    With insp
        'Referenz für IntelliSense
        Set wdDoc = .WordEditor
        With wdDoc
            If .Shapes.Count > 0 Then
                Set sh = .Shapes(1)
                With sh
                    'Ausgabe Inhalt Textbox
                    MsgBox "Inhalt der Textbox: " & vbNewLine & .TextFrame.TextRange.Text
                    'Wertzuweisung
                    .TextFrame.TextRange.Text = "Wertzuweisung"
                End With
            End If
        End With
    End With


FinisErr:
If err.Number <> 0 Then
 MsgBox err.Number & vbNewLine & err.Description
End If
'
Set insp = Nothing:    Set wdDoc = Nothing:    Set sh = Nothing
End Sub

Hinweis:

In Outlook muss ein Verweis auf die Word-Bibliothek gesetzt werden, dann funktioniert der Code und Du kannst die IntelliSense nutzen.

In VBE in Outlook: Extras -> Verweise -> M$ Word ....anhaken -> Ok