WdLanguageID ist nur der Bezeichner der Enumeration. Den braucht man nicht wirklich, aber wenn man ihn eingibt und dann den Scope-Operator (Punkt) dahinter setzt, bekommt man per Intelli-Sense eine Liste angezeigt; und darunter findet man dann auch wdGerman. ich schreibe dies meistens aus, da man so sicher geht dass man die richtige Konstante wählt. Es würde also auch schon reichen einfach wdGerman dort anzugeben - wd.German ist jedoch falsch.
Jap. Die For-Schleife ist der Teil mit PartOfSpeechList. Damit könntest du z.B. nach nur Synonymen mit der Bedeutung von Substantiven suchen.
Ich geb dir hier mal einen Vorschlag, der alles was er findet ausgibt:
Option Explicit
Sub Test()
'Verweis auf Word hinzufügen
' * VBA-Editor Menü 'Extras' -> 'Verweise...' -> Microsoft Word X.0 Object Library
Dim objWord As Word.Application
Dim objSynInfo As Word.SynonymInfo
Dim rngCell As Excel.Range
Dim vntMeaning As Variant
Dim vntSyn As Variant
Dim lngOffset As Long
'neue Word-Instanz erstellen
Set objWord = New Word.Application
'jede Zelle in der aktuellen Auswahl einzeln behandeln
For Each rngCell In Selection.Cells
'Thesarus/Synonyme für das Wort in der Zelle suchen
Set objSynInfo = objWord.SynonymInfo(rngCell.Text, wdGerman)
'für das aktuele Wort kann es mehrere Bedeutungen geben
'(z.B. für 'Gut' als Substantiv -> 'Anwesen', Bauernhof, ...; oder als Adjektiv -> die gut[en] Sitten)
lngOffset = 1
For Each vntMeaning In objSynInfo.MeaningList
'hier werden nun Synonyme unter der jeweiligen Bedeutung gesucht
'(z.B. 'Gut' mit der Bedeutung von z.B. 'Anwesen')
For Each vntSyn In objSynInfo.SynonymList(vntMeaning)
'spaltenweise - in der selben Zeile - ausgeben
rngCell.Offset(, lngOffset).Value = vntSyn
lngOffset = lngOffset + 1
Next
Next
Next
'Word-Instanz schließen
objWord.Quit False
End Sub
Das spuckt dann, so etwas aus:
Gebäude |
Haus |
Häuser |
Bau |
Bauten |
Bauwerk |
Bauwerke |
|
Heizung |
Ofen |
Heizkörper |
Radiator |
Kamin |
|
|
|
Schloss |
Palais |
Palast |
Burg |
Prunkhaus |
Kastell |
Veste |
... |
Lüftung |
Abzug |
Durchzug |
Entlüftung |
Klimaanlage |
Ventilation |
|
|
Gerade für "Schloss" wird es eine lange-laaaange Liste, da hier auch Verben verfügbar sind - die Frage ist, ob es Sinnvoll ist jene mit aufzunehmen.
Grüße
|