|
Hallo,
dieser Code verarbeitet alle Daten auf Tabelle2 Spalten-Weise. In der ersten Spalte müssen sich die Namen befinden. Ab der zweiten Spalte befinden sich die Daten:
Option Explicit
Option Compare Text
' ************************************************************************************************
' Autor und Copyright: Marc Wershoven - IT / EDV Dienstleistungen und Beratung
' Homepage: http://www.online-vba.de - E-Mail: info@online-vba.de
' ------------------------------------------------------------------------------------------------
' Wichtige Hinweise:
' - Verwendung der Quelltexte auf eigene Gefahr!
' - Bitte beachten Sie die Nutzungsbedingungen von www.online-vba.de!
' - Dieser Hinweis inkl. Autorennennung darf nicht entfernt werden!
' - Jede Weiterübermittlung, Veröffentlichung oder Verbreitung ist untersagt!
' - Eine kommerzielle/gewerbliche Verwendung ist nicht gestattet!
' ************************************************************************************************
' Diese Hinweise beziehen sich auf den Quelltext, wie dieser unter dem folgenden Link, unverändert
' als Original zu sehen ist und gelten nicht für Veränderungen durch Nutzer bzw. Dritte:
' www.online-vba.de/vba_tutorialuserform.php
' ************************************************************************************************
'Neuer Eintrag Schaltfläche Ereignisroutine
Private Sub CommandButton1_Click()
Dim lSpalte As Long
'Wenn der Benutzer einen neuen Eintrag erzeugen möchte,
'erstellen wir einen neuen Eintrag in der ListBox und markieren
'diesen, damit der Benutzer die Daten eintragen kann
lSpalte = 2 'Start in Zeile 2, Zeile 1 sind ja die überschriftrn
'Schleife solange etwas in der ersten Spalte in Tabelle 1 drin steht
Do While Trim(CStr(Tabelle2.Cells(1, lSpalte).Value)) <> ""
lSpalte = lSpalte + 1 'Nächste Spalte bearbeiten
Loop
'Nach Durchlauf dieser Schleife steht lZeile in der ersten leeren Zeile von Tabelle2
'Neuen Eintrag in die Tabelle2 schreiben, Spalte ID muss gefüllt sein, damit
'unsere Routinen die Zeile wiederfinden!
Tabelle2.Cells(1, lSpalte) = CStr("Neuer Eintrag Spalte " & lSpalte)
'Und neuen Eintrag in die UserForm eintragen
ListBox1.AddItem CStr("Neuer Eintrag Spalte " & lSpalte)
'Den neuen Eintrag markieren mit Hilfe des ListIndexes
ListBox1.ListIndex = ListBox1.ListCount - 1
'Durch das Click Ereignis der ListBox werden die Daten automatisch geladen
End Sub
'Löschen Schaltfläche Ereignisroutine
Private Sub CommandButton2_Click()
Dim lSpalte As Long
'Wenn kein Datensatz in der ListBox markiert wurde, wird die Routine beendet
If ListBox1.ListIndex = -1 Then Exit Sub
'Zum Löschen benötigen wir die Zeilennummer des ausgewählten Datensatzes
lSpalte = 2 'Start in Spalte 2, Spalte 1 sind ja die Überschriften
'Schleife solange etwas in der ersten Spalte in Tabelle 1 drin steht
Do While Trim(CStr(Tabelle2.Cells(1, lSpalte).Value)) <> ""
'Datensatz ID Spalte mit selektiertem Eintrag der ListBox vergleichen
If ListBox1.Text = Trim(CStr(Tabelle2.Cells(1, lSpalte).Value)) Then
'Eintrag gefunden, die ganze Spalte wird nun gelöscht
Tabelle2.Columns(lSpalte).Delete
'Die ListBox muss nun neu geladen werden!
Call UserForm_Initialize
If ListBox1.ListCount > 0 Then ListBox1.ListIndex = 0
Exit Do 'Vorzeitiges Ende, da der Datensatz schon gefunden ist
End If
lSpalte = lSpalte + 1 'Nächste Spalte bearbeiten
Loop
End Sub
'Speichern Schaltfläche Ereignisroutine
Private Sub CommandButton3_Click()
Dim lSpalte As Long
'Wenn kein Datensatz in der ListBox markiert wurde, wird die Routine beendet
If ListBox1.ListIndex = -1 Then Exit Sub
'Wir müssen prüfen, ob die ID Spalte auch gefüllt ist!!
If Trim(CStr(TextBox1.Text)) = "" Then
'Meldung ausgeben
MsgBox "Sie müssen mindestens einen Namen eingeben!", vbCritical + vbOKOnly, "FEHLER!"
'Abbrechen der Speicherroutine
Exit Sub
End If
'Ausbauoption: Prüfen, ob die ID in Tabelle2 Zeile 1 schon vorhanden ist!
'Zum Speichern benötigen wir die Zeilennummer des ausgewählten Datensatzes
lSpalte = 2 'Start in Spalte 2, Spalte 1 sind ja die Überschriften
'Schleife solange etwas in der ersten Spalte in Tabelle 1 drin steht
Do While Trim(CStr(Tabelle2.Cells(1, lSpalte).Value)) <> ""
'Datensatz ID Spalte mit selektiertem Eintrag der ListBox vergleichen
If ListBox1.Text = Trim(CStr(Tabelle2.Cells(1, lSpalte).Value)) Then
'Eintrag gefunden, TextBoxen in die Zellen schreiben
Tabelle2.Cells(1, lSpalte).Value = Trim(CStr(TextBox1.Text))
Tabelle2.Cells(2, lSpalte).Value = TextBox2.Text
Tabelle2.Cells(3, lSpalte).Value = TextBox3.Text
Tabelle2.Cells(4, lSpalte).Value = TextBox4.Text
Tabelle2.Cells(5, lSpalte).Value = TextBox5.Text
Tabelle2.Cells(6, lSpalte).Value = TextBox6.Text
'Die ListBox muss nun neu geladen werden
'allerdings nur, wenn sich der Name (ID) geändert hat
If ListBox1.Text <> Trim(CStr(TextBox1.Text)) Then
Call UserForm_Initialize
If ListBox1.ListCount > 0 Then ListBox1.ListIndex = 0
End If
Exit Do 'Vorzeitiges Ende, da der Datensatz schon gefunden ist
End If
lSpalte = lSpalte + 1 ' Nächste Spalte bearbeiten
Loop
End Sub
'Beenden Schaltfläche Ereignisroutine
Private Sub CommandButton4_Click()
Unload Me
End Sub
'Klick auf die ListBox Ereignisroutine
Private Sub ListBox1_Click()
Dim lSpalte As Long
'Wenn der Benutzer einen Namen anklickt, suchen wir
'diesen in der Tabelle2 heraus und tragen die Daten
'in die TextBoxen ein.
'Wir löschen standardmäßig alle bisherigen TextBoxen-Inhalte
TextBox1 = ""
TextBox2 = ""
TextBox3 = ""
TextBox4 = ""
TextBox5 = ""
TextBox6 = ""
'Nur wenn ein Eintrag selektiert/markiert ist
If ListBox1.ListIndex >= 0 Then
lSpalte = 2 'Start in Spalte 2, Spalte 1 sind ja die Überschriften
'Schleife solange etwas in der ersten Zeile in Tabelle 2 drin steht
Do While Trim(CStr(Tabelle2.Cells(1, lSpalte).Value)) <> ""
'Wenn wir den Namen aus der ListBox1 in der Tabelle2 Zeile 1
'gefunden haben, übertragen wir die anderen Spalteninhalte
'in die TextBoxen!
If ListBox1.Text = Trim(CStr(Tabelle2.Cells(1, lSpalte).Value)) Then
'TextBoxen füllen
TextBox1 = Trim(CStr(Tabelle2.Cells(1, lSpalte).Value))
TextBox2 = Tabelle2.Cells(2, lSpalte).Value
TextBox3 = Tabelle2.Cells(3, lSpalte).Value
TextBox4 = Tabelle2.Cells(4, lSpalte).Value
TextBox5 = Tabelle2.Cells(5, lSpalte).Value
TextBox6 = Tabelle2.Cells(6, lSpalte).Value
Exit Do 'Vorzeitiges Ende, da der Datensatz schon gefunden ist
End If
lSpalte = lSpalte + 1 'Nächste Spalte bearbeiten
Loop
End If
End Sub
Private Sub UserForm_Activate()
'Wenn die Eingabemaske angezeigt wird, markieren wir den ersten Namen
'jedoch nur, wenn auch Einträge in der Liste stehen
If ListBox1.ListCount > 0 Then ListBox1.ListIndex = 0
End Sub
'Startroutine, wird ausgeführt bevor die Eingabemaske angezeigt wird
Private Sub UserForm_Initialize()
Dim lSpalte As Long
'Alle TextBoxen leer machen
TextBox1 = ""
TextBox2 = ""
TextBox3 = ""
TextBox4 = ""
TextBox5 = ""
TextBox6 = ""
'In dieser Routine laden wir alle vorhandenen
'Einträge in die ListBox1
ListBox1.Clear 'Zuerst einmal die Liste leeren
lSpalte = 2 'Start in Spalte 2, Spalte 1 sind ja die Überschriften
'Schleife solange etwas in der ersten Zeile in Tabelle 1 drin steht
Do While Trim(CStr(Tabelle2.Cells(1, lSpalte).Value)) <> ""
'Aktuelle Spalte in die ListBox eintragen
ListBox1.AddItem Trim(CStr(Tabelle2.Cells(1, lSpalte).Value))
lSpalte = lSpalte + 1
Loop
End Sub
VG, BigBen
|