Du gibst nicht genau an was du letztendlich für ein Verhalten wünscht.

Daher kann ich unten im Quellcode nur erahnen ob es sich so verhält wie gewollt.

Allgemein gilt:

• Sprungmarken vermeiden! Dafür gibt es ja schließlich If-Then.

Mein Vorschlag:

Option Explicit

Sub Bsp()
  
  Dim retVal As Variant
  Dim msgResult As VbMsgBoxResult
  
  Do
    msgResult = MsgBox("Stimmt diese Zahl?" & vbNewLine & _
                      Worksheets("T1").Range("B3").Value, _
                    Buttons:=vbYesNo, _
                    Title:="Frage")
    
    If msgResult = vbYes Then
      
      Range("B4").Value = Range("B3").Value
      
      retVal = Application.InputBox( _
                      "Geben Sie noch eine Zahl ein" & vbNewLine & _
                      "", _
                    Title:="", _
                    Type:=1)
      
      If VarType(retVal) <> vbBoolean Then
        Range("B5").Value = retVal
      End If
      
    Else 'result = vbNo
      
      retVal = Application.InputBox( _
                      "Bitte geben Sie die richtige Zahl ein" & vbNewLine & _
                      "", _
                    Title:="Zahl Abfrage", _
                    Type:=1)
      
      If VarType(retVal) <> vbBoolean Then
        Worksheets("T1").Range("B3").Value = retVal
      End If
      
      Worksheets("T2").Range("B3").Value = retVal
    End If
    
  Loop Until (msgResult = vbYes) Or (VarType(retVal) = vbBoolean)
  
  Call MsgBox("Fertig.", vbInformation)
  
End Sub

InputBox oder Application.InputBox (zweite gibt es nur in Excel) liefern einem ggf. False (Datentyp: Boolean) und das willst du ja abfangen. Also kannst du nicht einfach eine Variable mit Datenentyp Integer angeben (da wird False zu 0 gecastet), zumal der Nutzer ja auch was eingeben könnte was keine Zahl ist und dann gibt es einen Laufzeitfehler (die Prüfung auf eine Zahl kommt übrigens hier durch die Angabe Type:=1 bei Application.InputBox).

Gruß