Option Explicit
Dim oWbTarget As Workbook                          'Bewerberliste
Dim oWbSource As Workbook                          'jede Beurteilungsmappe
Dim oWsh As Worksheet                              'jede Tabelle dazu
Dim rngFound As Range                              'Treffer Bewerber in Liste

'zum Test wurde [A1] bzw. [A:A] gewählt - also anpassen !!!!!!!!!!!!!!!!!!!!!

Sub DurchDateiliste()
Dim strPath As String                              'Pfad zu Mappen
Dim strMask As String                              'Dateimaske
Dim strFile As String                              'Datei finden

Application.ScreenUpdating = False

   strPath = "E:\Temp\"
   strMask = "*.xls?"

   strFile = Dir(strPath & strMask)                 'Pfad zu Mappen
   If Len(strFile) = 0 Then Exit Sub

   Set oWbTarget = ThisWorkbook

   strFile = strPath & strFile

   DurchArbeitsmappe strFile                       'Mappe auswerten

   Do
      strFile = Dir()
      If Len(strFile) = 0 Then Exit Do
      strFile = strPath & strFile
      DurchArbeitsmappe strFile                    'Mappe auswerten
   Loop

Application.ScreenUpdating = True

End Sub

Private Sub DurchArbeitsmappe(ByVal Dateipfad As String)

   Set oWbSource = Workbooks.Open(Dateipfad)

   For Each oWsh In oWbSource.Sheets
      If BewerberinListe(oWsh.Index) Then          'prüfe ob Wert in [A1] in Liste [A:A]
         Mittelwert                                'bilde Mittelwert
      End If
   Next oWsh

   oWbSource.Close False

End Sub

Private Sub Mittelwert()                                   'Kriterien selbst festlegen
Dim rngMustHave As Range                           'hier nur als Test ...

   Set rngMustHave = oWsh.UsedRange                '... alles rechts von [A1]
   Set rngMustHave = rngMustHave.Offset(0, 1).Resize(rngMustHave.Rows.Count, _
      rngMustHave.Columns.Count - 1)

   rngFound.Offset(0, 1).Value = _
      WorksheetFunction.Average(rngMustHave)       'Mittelwert neben Bewerber in Liste
   '
   ' weitere, erforderliche Aktionen, was mit Mittelwert so soll !!!!!!!!!!!!!!!!!!!!!
   '
      
End Sub

Function BewerberinListe(ByVal TabIndex As Long) As Boolean

   Set rngFound = oWbTarget.Sheets(1).Range("A:A").Find(oWbSource.Sheets(TabIndex).Range("A1").Value)
   If Not rngFound Is Nothing Then BewerberinListe = True
End Function