Public Sub Top_5_ausgeben()
  
  Dim wksQuelle         As Excel.Worksheet
  Dim wksZiel           As Excel.Worksheet
  Dim rngSichtbar       As Excel.Range
  Dim rngSichtbarOhneKopfzeile As Excel.Range
  Dim rngZeile          As Excel.Range
  Dim nZeilen           As Long
  
  Set wksQuelle = ThisWorkbook.Worksheets("Tabelle5") '<- ggf. anpassen
  Set wksZiel = ThisWorkbook.Worksheets("Tabelle13")  '<- ggf. anpassen
  
  If Not wksQuelle.AutoFilterMode Then
    Call MsgBox("AutoFilter ist nicht gesetzt, Vorgang angebrochen.")
    Exit Sub
  End If
  
  'sichtbare Zellen
  Set rngSichtbar = wksQuelle.AutoFilter.Range.SpecialCells(xlCellTypeVisible)
  'davon nur bestimmte Spalten
  Set rngSichtbar = Intersect(rngSichtbar, rngSichtbar.Worksheet.Range("C:E"))
  
  'Nothing abfangen
  If rngSichtbar Is Nothing Then
    Call MsgBox("Keine sichtbaren Daten")
    Exit Sub
  End If
  
  For Each rngZeile In rngSichtbar.Rows
    
    'nicht die Kopfzeile (= erste Zeile im Bereich)?
    If rngZeile.Row > rngSichtbar.Row Then
      
      If Not rngSichtbarOhneKopfzeile Is Nothing Then
        Set rngSichtbarOhneKopfzeile = Union(rngZeile, rngSichtbarOhneKopfzeile)
      Else
        Set rngSichtbarOhneKopfzeile = rngZeile
      End If
      
      nZeilen = nZeilen + 1
      
      'bei fünf Zeilen ist Schluss (Top5)
      If nZeilen > 4 Then
        Exit For
      End If
      
    End If
    
  Next rngZeile
  
  'wenn Daten gefunden, ...
  If Not rngSichtbarOhneKopfzeile Is Nothing Then
    
    'vor dem kopieren alten 'Kram' entfernen
    Call wksZiel.Range("A4").CurrentRegion.Clear
    '... an ihr Ziel kopieren.
    Call rngSichtbarOhneKopfzeile.Copy(Destination:=wksZiel.Range("A4"))
    
    Call MsgBox("Daten wurden kopiert.", vbInformation)
    
  Else
    Call MsgBox("Keine sichtbaren Daten (ohne Kopfzeile)")
  End If
  
End Sub

Versuch mal so.