Thema Datum  Von Nutzer Rating
Antwort
23.05.2013 13:31:05 Görgen
Solved
Blau Excel-Datei ind den Hauptspeicherladen ohne die Datei zu "öffnen"
 23.05.2013 14:15:10 Gast41488
Solved

Ansicht des Beitrags:
Von:
Gast41488		 Datum:
23.05.2013 14:15:10		 Views:
553		 Rating:
     
Antwort:
 Nein
Thema:
Excel-Datei ind den Hauptspeicherladen ohne die Datei zu "öffnen"

Da gibt es unterschiedliche Möglichkeiten, das hier wäre eine davon:

Option Explicit

Sub Beispiel()
  
  Dim vVal As Variant
  
  vVal = GetValue("D:\", "VglMappe.xlsx", "Tabelle1", "A1")
  
  If Not IsError(vVal) Then
    
    If ThisWorkbook.Worksheets(1).Range("A10").Value = vVal Then
    '-> Werte sind identisch
      '...
    Else
    '-> Werte sind unterschiedlich
      '...
    End If
    
  Else
    On Error Resume Next
    Err.Raise CLng(vVal)
    Call MsgBox(Prompt:=Err.Description & vbNewLine & vbNewLine & "(Fehler " & Err.Number & ")", _
                Title:="Fehler", _
                Buttons:=vbCritical)
    On Error GoTo 0
  End If
  
End Sub

Public Function GetValue( _
    ByVal Path As String, _
    ByVal File As String, _
    ByVal Table As String, _
    ByVal CellAddr As String _
) As Variant
  
  On Error GoTo ErrHandler
  
  Dim strRef As String
  
  If Right$(Path, 1) <> "\" Then Path = Path & "\"
  
  If Dir$(Path & File) <> "" Then
    strRef = "'" & Path & "[" & File & "]" & Table & "'!" & CellAddr
    strRef = Application.ConvertFormula(strRef, xlA1, xlR1C1)
    GetValue = ExecuteExcel4Macro(strRef)
  Else
    GetValue = CVErr(53) 'FileNotFound
  End If
  
  Exit Function
ErrHandler:
  GetValue = CVErr(Err.Number)
End Function

 

Ihre Antwort
  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen
Thema: Name: Email:



  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen

Thema Datum  Von Nutzer Rating
Antwort
23.05.2013 13:31:05 Görgen
Solved
Blau Excel-Datei ind den Hauptspeicherladen ohne die Datei zu "öffnen"
 23.05.2013 14:15:10 Gast41488
Solved