Bilder kann man hier einfach einfügen - per Rechtsklick in den Textbereich, oder durch die übliche Tastenkombination STRG+V.

Man kann außerdem Bereiche aus Excel hier als Tabelle - auf die gleiche Weise - einfügen und die Tabelle dann per Rechtsklick formatieren.

Also wie gesagt:

1. per Dialog Verzeichnis auswählen lassen und merken (Member-Variable m_strFolder)
2. die Eigenschaft TabIndex bei allen Kombinations-/Listenfeldern (was auch immer), Textfeld und Schaltfläche setzen, um deren Reihenfolge festzulegen
3. durch 2. wird bei jedem Enter (oder Tabulator) zum nächsten Steuerelement gesprungen (Schaltflächen müssen SetFocus im Click-Event aufrufen)
4. bei Klick/Enter auf OK-Schaltfläche wird nächstes Element in der Liste ausgewählt (solange bis keines mehr da)

... ungefähr so

Option Explicit

Private m_strFolder As String

Private Sub bntOK_Click()
  
  If ComboBox1.ListIndex >= 0 And ComboBox1.ListIndex < ComboBox1.ListCount - 1 Then
    
    '<Save_Inputs_Rename_File_here>
    
    ComboBox1.ListIndex = ComboBox1.ListIndex + 1
    txtDate1.SetFocus 'Fokus auf erstes Eingabefeld
    
  ElseIf ComboBox1.ListIndex = ComboBox1.ListCount - 1 Then
    
    MsgBox "Ende erreicht!", vbInformation
    
  ElseIf ComboBox1.ListCount > 0 Then
    
    ComboBox1.ListIndex = 0
    txtDate1.SetFocus 'Fokus auf erstes Eingabefeld
    
  End If
  
End Sub

Private Sub btnPickFolder_Click()
  
  Dim strFile As String
  
  With Application.FileDialog(msoFileDialogFolderPicker)
    
    .Title = "Foto-Verzeichnis auswählen..."
    
    If .Show = -1 Then
      
      m_strFolder = .SelectedItems(1) & "\"
      
      strFile = Dir$(m_strFolder & "*.jpg")
      Do While strFile <> ""
        ComboBox1.AddItem strFile
        strFile = Dir$()
      Loop
      
      If ComboBox1.ListCount > 0 Then
        ComboBox1.ListIndex = 0
      End If
      
    End If
    
  End With
  
End Sub