Thema Datum  Von Nutzer Rating
Antwort
26.01.2015 21:33:15 std
Solved
Blau Dateiname auslesen bis zum Zeichen "_"
 27.01.2015 09:20:49 Gast44920
*****
Solved
27.01.2015 14:51:02 Gast92763
Solved
28.01.2015 08:10:08 Gast62493
Solved

Ansicht des Beitrags:
Von:
Gast44920		 Datum:
27.01.2015 09:20:49		 Views:
803		 Rating:
     
Antwort:
 Nein
Thema:
Dateiname auslesen bis zum Zeichen "_"

Kann man - minimalistisch gehalten - ungefähr so lösen:

Option Explicit

Sub Bsp01()
  
  Dim strPath As String
  
  strPath = "D:\Verwaltung\"
  
'  If Right$(strPath, 1) <> "\" _
    Then strPath = strPath & "\"
  
  Dim strFile As String
  Dim strPart As String
  Dim strNr As String
  
  strNr = Trim$(ActiveSheet.Range("J7").Value)
  
  If strNr = "" Then
    Call MsgBox("Es ist keine Nummer im aktiven Blatt angegeben.", vbExclamation, "Vorgang abgebrochen")
    Exit Sub
  End If
  
  strFile = Dir$(strPath & strNr & "_Eingang_*.xlsx")
  If strFile = "" Then strFile = Dir$(strPath & strNr & "_Ausgang_*.xlsx")
  
  If strFile = "" Then
    Call MsgBox("Es wurde keine Datei in '" & strPath & "' für Nr. '" & strNr & "' gefunden.", _
                vbExclamation, _
                "Vorgang abgebrochen")
    Exit Sub
  End If
  
  Dim wkbDst As Excel.Workbook
  Dim wkbSrc As Excel.Workbook
  
  Set wkbDst = ActiveWorkbook 'ThisWorkbook (?)
  Set wkbSrc = Workbooks.Open(strPath & strFile, ReadOnly:=True) 'wird, nachdem es geöffnet wurde, autom. zur aktiven Arbeitsmappe
  
  With wkbDst.Sheets
    Call wkbSrc.Sheets(Array("RW1", "RW3", "RW8")).Copy(After:=.Item(.Count)) 'Blätter ans Ende einhängen
  End With
  
  Call wkbSrc.Close
  
End Sub

 

Ihre Antwort
  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen
Thema: Name: Email:



  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen

Thema Datum  Von Nutzer Rating
Antwort
26.01.2015 21:33:15 std
Solved
Blau Dateiname auslesen bis zum Zeichen "_"
 27.01.2015 09:20:49 Gast44920
*****
Solved
27.01.2015 14:51:02 Gast92763
Solved
28.01.2015 08:10:08 Gast62493
Solved