Thema Datum  Von Nutzer Rating
Antwort
07.07.2014 21:53:47 Ringo
NotSolved
Blau Text in Zelle finden.
 08.07.2014 02:34:51 Gast77579
Solved
09.07.2014 19:45:59 Gast94917
NotSolved
10.07.2014 02:58:15 Gast76318
NotSolved

Ansicht des Beitrags:
Von:
Gast77579		 Datum:
08.07.2014 02:34:51		 Views:
772		 Rating:
     
Antwort:
 Nein
Thema:
Text in Zelle finden.		 
Option Explicit

'////////////////////////////////////////////////////////////////
'// Makro zum anzeigen einer Zelle anhand der Beschriftung
'// des aufrufenden FormControls (nur CommandButton).
Public Sub ShowHeader()
  
  If ActiveSheet Is Nothing Then Exit Sub
  If Not TypeOf ActiveSheet Is Excel.Worksheet Then Exit Sub
  
  Dim shp As Excel.Shape
  
  Select Case TypeName(Application.Caller)
    Case "String"
      On Error Resume Next
      Set shp = ActiveSheet.Shapes(Application.Caller)
      On Error GoTo 0
  End Select
  
  If shp Is Nothing Then Exit Sub
  If shp.Type <> msoFormControl Then Exit Sub
  If shp.FormControlType <> xlButtonControl Then Exit Sub
  
  Dim rngHeaderCell As Excel.Range
  
  With ActiveSheet.Columns("A") '<- hier ggf. den Suchbereich anpassen
    
    Set rngHeaderCell = .Find(shp.OLEFormat.Object.Caption, LookIn:=xlValues, LookAt:=xlWhole)
    
    If rngHeaderCell Is Nothing Then
      Call MsgBox("Die Überschrift '" & shp.OLEFormat.Object.Caption & "' wurde nicht gefunden.", _
                  vbExclamation)
    Else
      rngHeaderCell.Activate
    End If
    
  End With
  
End Sub

Füge deinem Tabellenblatt beliebig viele Schaltflächen (Formulasteuerelement !!!) hinzu und weise ihnen jeweils das obige Makro zu.

Dann brauchst du nur noch die Beschriftung der Schaltflächen entsprechend der zu suchenden Überschrift zu setzen und fertig (Groß-/Kleinschreibung wird bei der Suche nicht unterschieden).

 

PS: Bitte beachte vorhandene Kommentare.

 

Gruß

Ihre Antwort
  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen
Thema: Name: Email:



  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen

Thema Datum  Von Nutzer Rating
Antwort
07.07.2014 21:53:47 Ringo
NotSolved
Blau Text in Zelle finden.
 08.07.2014 02:34:51 Gast77579
Solved
09.07.2014 19:45:59 Gast94917
NotSolved
10.07.2014 02:58:15 Gast76318
NotSolved