Hallo Nicole,

Hier habe ich einen Vorschlag für dich.

Viel Erfolg und einen schönen Abend
Heiko

Public Sub subLeereZeilenAusblenden()
'Durchsucht alle Arbeitsblätter dieser Datei.
'Blendet alle Zeilen aus, in denen außer dem Zeilentitel kein Werte stehen.
'Die Spalte des Zeilentitels ist parametriesiert.

  'Hier die Spaltennummer der Zeilentitel eintragen
  Const c_lngSpalteZeilenTitel As Long = 2  'Spalte B
  
  Dim wks As Excel.Worksheet
  Dim lngZeile As Long
  Dim lngErsteZeile As Long
  Dim lngLetzteZeile As Long
  Dim lngSpalte
  Dim lngLetzteSpalte As Long
  Dim rngZeilenTitel As Excel.Range
  Dim rngZelle As Excel.Range
  
  'letzte Zeile und letzte Spalte bestimmen
  Set wks = ThisWorkbook.Worksheets(1)
  lngLetzteZeile = wks.Rows.Count
  lngLetzteSpalte = wks.Columns.Count
  
  For Each wks In ThisWorkbook.Worksheets
      
    'erste Zeile bestimmen
    lngZeile = 1
    Set rngZeilenTitel = wks.Cells(lngZeile, c_lngSpalteZeilenTitel)
    Do Until rngZeilenTitel.Value <> ""
      lngZeile = lngZeile + 1
      Set rngZeilenTitel = wks.Cells(lngZeile, c_lngSpalteZeilenTitel)
    Loop
    
    'alle Zeilen durchsuchen und ausblenden, wenn leer
    Do Until rngZeilenTitel = "" Or lngZeile = lngLetzteZeile + 1
      lngSpalte = c_lngSpalteZeilenTitel + 1
      Set rngZelle = wks.Cells(lngZeile, lngSpalte)
      Do Until rngZelle <> "" Or lngSpalte = lngLetzteSpalte
        lngSpalte = lngSpalte + 1
        Set rngZelle = wks.Cells(lngZeile, lngSpalte)
        If rngZelle = "" And lngSpalte = lngLetzteSpalte Then
          wks.Rows(lngZeile).Hidden = True
        End If
      Loop
      lngZeile = lngZeile + 1
      If lngZeile <= lngLetzteZeile Then
        Set rngZeilenTitel = wks.Cells(lngZeile, c_lngSpalteZeilenTitel)
      End If
    Loop
  Next wks
  
  Set rngZeilenTitel = Nothing
  Set rngZelle = Nothing
  Set wks = Nothing

End Sub